add home-assistant nix configuration

2023-12-09 22:55:41 +01:00
parent bdca649697
commit 027be96f9c
22 changed files with 1450 additions and 60 deletions
--- a/hosts/fw.cloonar.com/modules/home-assistant/default.nix
+++ b/hosts/fw.cloonar.com/modules/home-assistant/default.nix
@@ -0,0 +1,183 @@
+{ config, pkgs, ... }:
+let
+  domain = "home-assistant.cloonar.com";
+in
+{
+  users.users.hass = {
+    home = "/var/lib/hass";
+    createHome = true;
+    group = "hass";
+    uid = config.ids.uids.hass;
+  };
+  users.groups.hass.gid = config.ids.gids.hass;
+
+  security.acme.certs."${domain}" = {
+    group = "nginx";
+  };
+
+  sops.secrets."home-assistant-secrets.yaml" = {
+    owner = "hass";
+    restartUnits = [ "container@hass.service" ];
+  };
+
+  sops.secrets."home-assistant-ldap" = {
+    owner = "hass";
+  };
+
+  containers.hass = {
+    autoStart = true;
+    ephemeral = true; # because of ssh key
+    macvlans = [ "vserver" ];
+    bindMounts = {
+      "/var/lib/hass" = {
+        hostPath = "/var/lib/hass/";
+        isReadOnly = false;
+      };
+      "/var/lib/acme/hass/" = {
+        hostPath = "${config.security.acme.certs.${domain}.directory}";
+        isReadOnly = true;
+      };
+      "/run/secrets/home-assistant-ldap" = {
+        hostPath = config.sops.secrets."home-assistant-ldap".path;
+        isReadOnly = true;
+      };
+      "/var/lib/hass/secrets.yaml" = {
+        hostPath = config.sops.secrets."home-assistant-secrets.yaml".path;
+        isReadOnly = true;
+      };
+    };
+    config = { lib, config, pkgs, ... }: {
+      imports = [
+        ./ac.nix
+        # ./aeg.nix
+        ./battery.nix
+        ./enocean.nix
+        ./ldap.nix
+        ./light.nix
+        ./locks.nix
+        ./multimedia.nix
+        ./notify.nix
+        ./pc.nix
+        ./pushover.nix
+        ./roborock.nix
+        ./scene-switch.nix
+        ./sleep.nix
+        ./snapcast.nix
+      ];
+
+      networking = {
+        hostName = "home-assistant";
+        nameservers = [ "10.42.97.10" ];
+        interfaces.mv-vserver = {
+          useDHCP = true;
+        };
+        firewall = {
+          enable = true;
+          allowedTCPPorts = [ 80 443 ];
+          allowedUDPPorts = [ 5683 ];
+        };
+      };
+
+      services.nginx.enable = true;
+      services.nginx.virtualHosts."${domain}" = {
+        sslCertificate = "/var/lib/acme/hass/fullchain.pem";
+        sslCertificateKey = "/var/lib/acme/hass/key.pem";
+        sslTrustedCertificate = "/var/lib/acme/hass/chain.pem";
+        forceSSL = true;
+        extraConfig = ''
+          proxy_buffering off;
+        '';
+        locations."/".extraConfig = ''
+          proxy_pass http://127.0.0.1:8123;
+          proxy_set_header Host $host;
+          proxy_redirect http:// https://;
+          proxy_http_version 1.1;
+          proxy_set_header X-Forwarded-For $proxy_add_x_forwarded_for;
+          proxy_set_header Upgrade $http_upgrade;
+          proxy_set_header Connection $connection_upgrade;
+        '';
+      };
+
+      services.home-assistant = {
+        enable = true;
+      };
+
+      services.home-assistant.extraComponents = [
+        "mobile_app"
+        "backup"
+        "denonavr"
+        "androidtv"
+        "rainbird"
+      ];
+
+      services.home-assistant.config =
+        let
+          hiddenEntities = [
+            "sensor.last_boot"
+            "sensor.date"
+          ];
+        in
+        {
+          homeassistant = {
+            name = "Home";
+            latitude = "!secret home_latitude";
+            longitude = "!secret home_longitude";
+            elevation = "!secret home_elevation";
+            unit_system = "metric";
+            currency = "EUR";
+            country = "AT";
+            time_zone = "Europe/Vienna";
+            external_url = "https://${domain}";
+          };
+          automation = "!include automations.yaml";
+          frontend = { };
+          http = {
+            use_x_forwarded_for = true;
+            trusted_proxies = [
+              "127.0.0.1"
+              "::1"
+            ];
+          };
+          history.exclude = {
+            entities = hiddenEntities;
+            domains = [
+              "automation"
+              "updater"
+            ];
+          };
+          "map" = { };
+          enocean = {
+            device = "/dev/serial/by-id/usb-EnOcean_GmbH_EnOcean_USB_300_DC_FT5OI9YG-if00-port0";
+          };
+          # logbook.exclude.entities = "hiddenEntities";
+          logger = {
+            default = "info";
+          };
+
+          #icloud = {
+          #  username = "!secret icloud_email";
+          #  password = "!secret icloud_password";
+          #  with_family = true;
+          #};
+          network = { };
+          zeroconf = { };
+          system_health = { };
+          default_config = { };
+          system_log = { };
+          sensor = [
+            {
+              platform = "template";
+              sensors.bedtime_alarm = {
+                friendly_name = "Bedtime Alarm";
+                value_template = "09:00";
+              };
+            }
+          ];
+        };
+
+      users.users.hass.extraGroups = [ "dialout" ];
+
+      system.stateVersion = "23.05";
+    };
+  };
+}