add pkgs and overlays to nb config

2023-08-20 14:41:04 +02:00
parent e2353a4f97
commit 7a0d60c17c
32 changed files with 8917 additions and 0 deletions
--- a/hosts/nb-01.cloonar.com/pkgs/alacritty/default.nix
+++ b/hosts/nb-01.cloonar.com/pkgs/alacritty/default.nix
@@ -0,0 +1,115 @@
+{ stdenv
+, lib
+, fetchFromGitHub
+, fetchpatch
+, rustPlatform
+, nixosTests
+
+, cmake
+, installShellFiles
+, makeWrapper
+, ncurses
+, pkg-config
+, python3
+
+, expat
+, fontconfig
+, freetype
+, libGL
+, xorg
+, libxkbcommon
+, wayland
+, xdg-utils
+}:
+let
+  rpathLibs = [
+    expat
+    fontconfig
+    freetype
+    libGL
+    xorg.libX11
+    xorg.libXcursor
+    xorg.libXi
+    xorg.libXrandr
+    xorg.libXxf86vm
+    xorg.libxcb
+  ] ++ lib.optionals stdenv.isLinux [
+    libxkbcommon
+    wayland
+  ];
+in
+rustPlatform.buildRustPackage rec {
+  pname = "alacritty";
+  version = "0.12.0-2";
+
+  src = fetchFromGitHub {
+    owner = "alacritty";
+    repo = pname;
+    rev = "db903503df024a3f5066937fbe0272be88226738";
+    hash = "sha256-XZ75sbXFWCsCvebGK8O+7Ulm00/1/yEcT9dOIAk5Vzg=";
+  };
+
+  cargoSha256 = "sha256-popq3LbSdw5mML96J4TPGPtWFGdBrYfFqdj1yvWU8Vk=";
+
+  nativeBuildInputs = [
+    cmake
+    installShellFiles
+    makeWrapper
+    ncurses
+    pkg-config
+    python3
+  ];
+
+  outputs = [ "out" "terminfo" ];
+
+  postPatch = lib.optionalString (!xdg-utils.meta.broken) ''
+    substituteInPlace alacritty/src/config/ui_config.rs \
+      --replace xdg-open ${xdg-utils}/bin/xdg-open
+  '';
+
+  checkFlags = [ "--skip=term::test::mock_term" ]; # broken on aarch64
+
+  postInstall = (
+    ''
+      install -D extra/linux/Alacritty.desktop -t $out/share/applications/
+      install -D extra/linux/org.alacritty.Alacritty.appdata.xml -t $out/share/appdata/
+      install -D extra/logo/compat/alacritty-term.svg $out/share/icons/hicolor/scalable/apps/Alacritty.svg
+
+      # patchelf generates an ELF that binutils' "strip" doesn't like:
+      #    strip: not enough room for program headers, try linking with -N
+      # As a workaround, strip manually before running patchelf.
+      $STRIP -S $out/bin/alacritty
+
+      patchelf --set-rpath "${lib.makeLibraryPath rpathLibs}" $out/bin/alacritty
+    ''
+  ) + ''
+
+    installShellCompletion --zsh extra/completions/_alacritty
+    installShellCompletion --bash extra/completions/alacritty.bash
+    installShellCompletion --fish extra/completions/alacritty.fish
+
+    install -dm 755 "$out/share/man/man1"
+    gzip -c extra/alacritty.man > "$out/share/man/man1/alacritty.1.gz"
+    gzip -c extra/alacritty-msg.man > "$out/share/man/man1/alacritty-msg.1.gz"
+
+    install -Dm 644 alacritty.yml $out/share/doc/alacritty.yml
+
+    install -dm 755 "$terminfo/share/terminfo/a/"
+    tic -xe alacritty,alacritty-direct -o "$terminfo/share/terminfo" extra/alacritty.info
+    mkdir -p $out/nix-support
+    echo "$terminfo" >> $out/nix-support/propagated-user-env-packages
+  '';
+
+  dontPatchELF = true;
+
+  passthru.tests.test = nixosTests.terminal-emulators.alacritty;
+
+  meta = with lib; {
+    description = "A cross-platform, GPU-accelerated terminal emulator";
+    homepage = "https://github.com/alacritty/alacritty";
+    license = licenses.asl20;
+    maintainers = with maintainers; [ Br1ght0ne mic92 ];
+    platforms = platforms.unix;
+    changelog = "https://github.com/alacritty/alacritty/blob/v${version}/CHANGELOG.md";
+  };
+}