add pkgs and overlays to nb config

2023-08-20 14:41:04 +02:00
parent e2353a4f97
commit 7a0d60c17c
32 changed files with 8917 additions and 0 deletions
--- a/hosts/nb-01.cloonar.com/pkgs/linux-enable-ir-emitter/default.nix
+++ b/hosts/nb-01.cloonar.com/pkgs/linux-enable-ir-emitter/default.nix
@@ -0,0 +1,51 @@
+{ stdenv
+, lib
+, makeWrapper
+, fetchFromGitHub
+, fetchurl
+, meson
+, ninja
+, pkg-config
+, python3
+, opencv
+, usbutils
+}:
+stdenv.mkDerivation rec {
+  pname = "linux-enable-ir-emitter";
+  version = "4.5.0";
+
+  src = fetchFromGitHub {
+    owner = "EmixamPP";
+    repo = pname;
+    rev = version;
+    hash = "sha256-Dv1ukn2TkXfBk1vc+6Uq7tw8WwCAfIcKl13BoOifz+Q=";
+  };
+
+  patches = [
+    # Prevent `linux-enable-ir-emitter configure` from trying to enable systemd service, NixOS manages those declaratively.
+    ./remove-boot-set.patch
+  ];
+
+  nativeBuildInputs = [
+    makeWrapper
+    meson
+    ninja
+    pkg-config
+  ];
+  buildInputs = [
+    python3
+    opencv
+  ];
+
+  postInstall = ''
+    wrapProgram $out/bin/${pname} --prefix PATH : ${lib.makeBinPath [usbutils]}
+  '';
+
+  meta = {
+    description = "Provides support for infrared cameras that are not directly enabled out-of-the box";
+    homepage = "https://github.com/EmixamPP/linux-enable-ir-emitter";
+    license = lib.licenses.mit;
+    maintainers = with lib.maintainers; [ fufexan ];
+    platforms = lib.platforms.linux;
+  };
+}