fix: pyload

utils/overlays/packages.nix

@@ -6,5 +6,15 @@ self: super: {
   openmanus = (super.callPackage ../pkgs/openmanus.nix { });
   ai-mailer = self.callPackage ../pkgs/ai-mailer.nix { };
 
+  # Python packages
+  python3 = super.python3.override {
+    packageOverrides = pself: psuper: {
+      mini-racer = pself.callPackage ../pkgs/mini-racer.nix { };
+    };
+  };
+  python3Packages = self.python3.pkgs;
+
+  pyload-ng = self.callPackage ../pkgs/pyload-ng-updated.nix { pyload-ng = super.pyload-ng; };
+
   # vscode-insiders = (super.callPackage ../pkgs/vscode-insiders.nix { });
 }

utils/pkgs/mini-racer.nix

@@ -0,0 +1,41 @@
+{ lib
+, buildPythonPackage
+, fetchPypi
+, stdenv
+, autoPatchelfHook
+}:
+
+buildPythonPackage rec {
+  pname = "mini-racer";
+  version = "0.12.4";
+  format = "wheel";
+
+  src = fetchPypi {
+    pname = "mini_racer";
+    inherit version format;
+    dist = "py3";
+    python = "py3";
+    abi = "none";
+    platform = "manylinux_2_31_x86_64";
+    hash = "sha256-aaHETQKpBpuIFoTO8VotdH/gdD3ynq3Igf2nACquX9I=";
+  };
+
+  nativeBuildInputs = [
+    autoPatchelfHook
+  ];
+
+  buildInputs = [
+    stdenv.cc.cc.lib
+  ];
+
+  # Don't strip binaries, it breaks V8
+  dontStrip = true;
+
+  meta = with lib; {
+    description = "Minimal Python wrapper for V8 JavaScript engine";
+    homepage = "https://github.com/bpcreech/PyMiniRacer";
+    license = licenses.isc;
+    maintainers = [ ];
+    platforms = [ "x86_64-linux" ];
+  };
+}

utils/pkgs/pyload-ng-updated.nix

@@ -0,0 +1,21 @@
+{ lib, pyload-ng, fetchFromGitHub, python3Packages }:
+
+pyload-ng.overridePythonAttrs (oldAttrs: rec {
+  version = "0.5.0b3.dev93+git";
+
+  src = fetchFromGitHub {
+    owner = "pyload";
+    repo = "pyload";
+    rev = "3115740a2210fd57b5d050cd0850a0e61ec493ed"; # [DdownloadCom] fix #4537
+    hash = "sha256-g1eEeNnr3Axtr+0BJzMcNQomTEX4EsUG1Jxt+huPyoc=";
+  };
+
+  # Add new dependencies required in newer versions
+  propagatedBuildInputs = (oldAttrs.propagatedBuildInputs or []) ++ (with python3Packages; [
+    mini-racer
+    packaging
+    pydantic
+    flask-wtf
+    defusedxml
+  ]);
+})