{ pkgs, lib, ... }:
let
mopidy-autoplay = pkgs.python3Packages.buildPythonApplication rec {
  pname = "Mopidy-Autoplay";
  version = "0.2.3";

  src = pkgs.python3Packages.fetchPypi {
    inherit pname version;
    sha256 = "sha256-E2Q+Cn2LWSbfoT/gFzUfChwl67Mv17uKmX2woFz/3YM=";
  };

  propagatedBuildInputs = [
    pkgs.mopidy
  ] ++ (with pkgs.python3Packages; [
    configobj
  ]);

  # no tests implemented
  doCheck = false;

  meta = with lib; {
    homepage = "https://codeberg.org/sph/mopidy-autoplay";
  };
};
in
{
  services.mopidy = {
    enable = true;
    extensionPackages = [ pkgs.mopidy-iris pkgs.mopidy-tunein mopidy-autoplay ];
    configuration = ''
      [audio]
      output = audioresample ! audioconvert ! audio/x-raw,rate=48000,channels=2,format=S16LE ! wavenc ! filesink location=/run/snapserver/mopidy

      [file]
      enabled = false

      [autoplay]
      enabled = true
    '';
  };

  services.nginx.virtualHosts."mopidy.cloonar.com" = {
    forceSSL = true;
    enableACME = true;
    acmeRoot = null;
    extraConfig = ''
      proxy_buffering off;
    '';
    locations."/".extraConfig = ''
      proxy_pass http://127.0.0.1:6680;
      proxy_set_header Host $host;
      proxy_redirect http:// https://;
      proxy_http_version 1.1;
      proxy_set_header X-Forwarded-For $proxy_add_x_forwarded_for;
      proxy_set_header Upgrade $http_upgrade;
      proxy_set_header Connection $connection_upgrade;
    '';
  };
}